{
  lib,
  newScope,
  inputs,
}:

lib.makeScope newScope (self: {
  inherit inputs;
  inherit (self.inputs)
    libkrun-src
    muvm-src
    sidebus-src
    wl-backdrop-src
    ;
  libkrunfw = self.callPackage ./packages/libkrunfw {
    # libkrunfw-src = libkrunfw-src;
  };
  libkrun = self.callPackage ./packages/libkrun { };
  mesa = self.callPackage ./packages/mesa { };
  muvm = self.callPackage ./packages/muvm {
    muvm-src = self.inputs.muvm-src;
  };
  munix = self.callPackage ./packages/munix { };
  wl-cross-domain-proxy = self.callPackage ./packages/wl-cross-domain-proxy { };
  sidebusPackages = self.callPackage (self.inputs.sidebus-src + "/scope.nix") { };
  inherit (self.sidebusPackages) sidebus-agent sidebus-broker;
  wl-backdrop = self.callPackage (
    {
      lib,
      rustPlatform,
    }:
    let
      src = self.wl-backdrop-src;
      cargoToml = fromTOML (builtins.readFile (src + "/Cargo.toml"));
      fs = lib.fileset;
    in
    rustPlatform.buildRustPackage {
      pname = cargoToml.package.name;
      inherit (cargoToml.package) version;
      src = fs.toSource {
        root = src;
        fileset = fs.unions [
          (src + "/src")
          (src + "/Cargo.toml")
          (src + "/Cargo.lock")
        ];
      };
      cargoLock = src + "/Cargo.lock";
    }
  ) { };
})